Active Server Pages スクリプトのデバッグ

スクリプトを作成する際は、そのスクリプトが技術的におよび構文的に正確であることが必要です。スクリプトに誤りがあると、正常に実行できなかったり、エラーメッセージが表示されたりします。これらのエラーメッセージの原因を調べてエラーを解決する作業のことをデバッグと呼びます。スクリプトのテストを十分に行い、必要なデバッグを行うことによって、Web サイトを訪問するすべてのユーザーが、エラーメッセージを見ることなく意図したとおりの動作を体験できるようにしてください。

エラーメッセージは HTML として送り返されますが、エラーの種類に応じて次の情報の一部または全部がいっしょに返されます。

エラーの発生したスクリプト言語
エラー番号
エラーの簡単な説明
.asp ファイルの名前
エラーが発生した行の番号
エラーが発生したソースコード
エラーの詳細な説明とその解決方法

注意行番号を表示するテキストエディタを使えば、.asp ファイル内のエラー行を調べるのに便利です。

これらの情報を使って .asp ファイルを修正し、エラーを解決します。深刻なエラーについては、クライアントブラウザだけでなく、Windows NT や Internet Information Server (IIS) のログにも送られます。それ以外のエラーは IIS のログとクライアントブラウザに送られます。

VBScript によるエラー処理

On Error Resume Next ステートメント

.asp ファイル内にエラーが見つかると、スクリプトの処理が中断されてエラーメッセージがブラウザに返されます。エラーが見つかった場合でもページの処理を続けたい場合には、次の行を .asp ファイルの先頭に追加します。

<% On Error Resume Next %>

注意 On Error Resume Next ステートメントは VBScript のステートメントであり、VBScript で記述されているスクリプトに対してのみ作用します。.asp ファイルに JScript が含まれている場合、JScript ではエラー後再開に相当する機能がないため、このステートメントを使っても JScript のエラーのデバッグには何の効果もありません。VBScript から JScript の関数を呼び出してその関数によってエラーが生じた場合は、エラーメッセージがブラウザに返され、その位置で .asp ファイルの処理が中断します。

On Error Resume Next ステートメントは、実際にエラーを解決するものではありません。エラーを手動で解決するには、Err.Clear メソッドを使います。

<HTML>
<HEAD>
<TITLE>On Error Resume Next および Err.Clear によるエラー処理</TITLE> 
</HEAD>
<BODY>
<% 
Call DoSafeDivide(1, 3) 
Call DoSafeDivide(1, 0) 
%>

<SCRIPT LANGUAGE="VBScript" RUNAT=Server>

Sub DoSafeDivide(x, y)
 
       On Error Resume Next

       z = x / y
       If Err.Number > 0 Then
 	 Response.Write("割り算に失敗しました:  " & x & " / " & y & "<BR>")
 	 Response.Write("エラー元: " & Err.Source & "<BR>")
 	 Response.Write("エラー番号: " & Err.Number & "<BR>")
 	 Response.Write("エラーの説明: " & Err.Description & "<BR>")
               Err.Clear
       Else
 	 Response.Write("割り算に成功しました: " & x & " / " & y & " = " & z & "<BR>")
       End If
End Sub

</SCRIPT>
</BODY>
</HTML>

For...Each ステートメント

コレクションに対して繰り返しデバッグ作業を行う場合に、For...Each ステートメントを使ってスクリプト内のコレクションのすべての変数を返すことにより作業を簡単にすることができます。たとえば、次のスクリプト例は、Request オブジェクトの QueryString コレクションに対して For...Each ステートメントを使い、QueryString コレクション内のすべてのキーに対するすべての値を返します。

<% For Each Key In Request.QueryString %>
  <%= Key %> = <%= Request.QueryString(Key) %><br>
  <% ValueCount = Request.QueryString(Key).Count
    If ValueCount > 1 Then %>
      <%= Key %> に対して <%= ValueCount %> 個の値があります。<br>
    <% For i = 1 To ValueCount %>
        値 <%= i %> は <b><%= Request.QueryString(Key)(i) %></b><br>
    <% Next
    End If   
  Next
%>

VBScript のエラーでは、次の例のようにエラーの正確な位置を示すポインタをスクリプトコード内に出力することができます。

Microsoft VBScript compilation error '800a03f3' 

Expected '=' 

/ASPSamp/Samples/outstrem.asp, line 11 

Set OutStream Nothing
-------------^

JScript によるエラー処理

JScript では、通常次のような間違いがエラーの原因となります。

綴りの間違い。
大文字小文字の区別の間違い (JScript は大文字小文字を区別します)。
角かっこ、かっこ、単一引用符、二重引用符が対応していない。

JScript のデバッグでは以上のようなエラーについて常にチェックしてください。

フォームのデバッグ

Request オブジェクトの QueryString コレクション内の変数を受け取るときに、Form コレクション内にあるべき変数を受け取った場合は、HTML の <FORM> タグで METHOD=POST を設定していないか確認してください。QueryString コレクションにフォーム変数を渡すのは GET メソッドです。POST メソッドは Form コレクションにフォーム変数を渡します。